StockFetcher Forums · Filter Exchange · Who really wants to find the next NTRI?<< 1 ... 17 18 19 20 21 ... 31 >>Post Follow-up
rtucker
318 posts
msg #42882
- Ignore rtucker		 4/11/2006 12:06:56 AM

Congrats stocktrader. Your'e a generous person. There was a thread "watchlist or anything that moves?" I am interested if you were always in this small watchlist group or was this thread a beginning to a change of methods?

I think it is interesting (for me anyway) to see what stocks this screen might have turned up; 12/01/2004 through 5/01/05. This time period was the last relatively steep downturn of qqqq's. By, using this "next ntri" criteria and Cegis' backtest trick it is clear that even during this 100 day period a good 20 or so "movers" could be found and traded. At least by you that is !

Fetcher[set{rtn1,price / price 100 days ago}
set{rtn2,rtn1 - 1}
set{rtn,rtn2 * 100}

*/filter goes here*/
price 100 days ago is between 1 and 20 and avg vol(90) > 300000

add column rtn
and rtn > 0
and sort column 5 descending
offset 5/1/2005]
stocktrader
294 posts
msg #42886
- Ignore stocktrader		 4/11/2006 8:56:59 AM

rtucker,

Thanks, but I was not part of that thread/group.

I see many good plays in your filter. Really got me excited to see some of them. You're right, many movers.

One reason I like the Next NTRI filter is that it has "movers" as you said.

I call this my popcorn filter. A group of stocks (Little kernals of corn) that are heating up and pop. Every day if I can get one or two that pop, this is good. For me trading is a function of time. In the past, I've been a long term holder of stocks (1+ year hold) just find out that I get 20% gain on the portfolio for the year. Although 20% is good in terms of banks, etc.....it always could be better :)

Watching OLAB today for a potential short.......pretty scary!




stocktrader
294 posts
msg #42887
- Ignore stocktrader		 4/11/2006 9:32:14 AM

Just tried to short OLAB......no shares available to short....
Probably a good thing....maybe it goes up :)
stocktrader
294 posts
msg #42888
- Ignore stocktrader		 4/11/2006 10:13:19 AM

How about that OLAB! I'm drueling.....
fixme1too
7 posts
msg #42889
- Ignore fixme1too		 4/11/2006 11:56:11 AM

Hello all new here to the forum just was wondering is there a good filter here the would indicate stocks that would be good for shorting. If the trends filter is it what do we look for in the filter that would indicate a particular stock would be good to short.
stocktrader
294 posts
msg #42890
- Ignore stocktrader		 4/11/2006 12:19:08 PM

Welcome.

The Next NTRI filter will work. Watch the WARM display.

Shorted LNUX today, which is in the filter.

Done for the day with a measly $650, in a bloody market yet.




fixme1too
7 posts
msg #42891
- Ignore fixme1too		 4/11/2006 12:35:54 PM

hey stocktrader ran the april 10th NTRI filter didnt see LNUX on it. Which NTRI did u use and what in the WARM portion of the filter prompted u to choose LNUX to short LOL about ur 650.00 for today. Im just starting with 3,000.00 Would love to get 650.00 for the week LOL
stocktrader
294 posts
msg #42895
- Ignore stocktrader
modified		 4/11/2006 2:33:27 PM

Yes, I keep messing with TRO's nice work.

Here's my hacked version for shorting.
Remember, the filter has to be "Traded" None of these are blind picks where one just buys them and makes money.

With 3k it makes it very difficult to make money when considering the broker fee. Think about diversification and longer term holds. Take a look at TRO's original filter, it is pretty slick.


Fetcher[/* FINDING THE NEXT NTRI FILTER */

/* TREND DISPLAY */

set{T03, count(3 day slope of the close above 0,1)}
set{T05, count(5 day slope of the close above 0,1)}
set{T10, count(10 day slope of the close above 0,1)}
set{T60, count(60 day slope of the close above 0,1)}
set{T200, count(200 day slope of the close above 0,1)}

set{V10, count(average volume(3) below volume,1)}
set{V60, count(average volume(15) below volume,1)}
set{V200, count(average volume(30) below volume,1)}

Set{av1, V200 * 1}
Set{av2, V60 * 10}
Set{av3, V10 * 100}

Set{a1, T200 * 1}
Set{a2, T60 * 10}
Set{a3, T10 * 100}

Set{et1, T10 * 1}
Set{et2, T05 * 10}
Set{et3, T03 * 100}
Set{etzenith,50}

Set{t1, T200 * 100}
Set{t2, T60 * 100}
Set{t3, T10 * 100}
Set{t12, t1 + t2}
Set{t123,t12 + t3}

Set{v1, V200 * 100}
Set{v2, V60 * 100}
Set{v3, V10 * 100}
Set{v12, v1 + v2}
Set{v123,v12 + v3}

Set{aa, a1 + a2}
Set{TREND, aa + a3}

Set{aav, av1 + av2}
Set{TRENDV, aav + av3}

Set{et, et1 + et2}
Set{TRENDE, et + et3}
set{T03a,days(3 day slope of the close below 0, 100)}
set{T05a,days(5 day slope of the close below 0, 100)}
set{T10a,days(10 day slope of the close below 0, 100)}

draw T03a
draw T05a on plot T03a
draw T10a on plot T03a
draw etzenith on plot T03a

/* dvpct - percentage dollar volume increased(+)/decreased(-) */

set{dv1, close 1 day ago * volume 1 day ago }
set{dv, close * volume }
set{netdvchg, dv - dv1}
set{dvpc, netdvchg / dv1 }
set{dvpct, dvpc * 100}

/* valchg - percentage value increased(+)/decreased(-) */

set{netchg, close - close 1 day ago}
set{CCC, netchg / close 1 day ago}
set{VVV, volume / volume 1 day ago}
set{CCCVVV, CCC * VVV}
set{valchg, CCCVVV * 100 }

Set{tcross,250}
Set{tzenith,400}
Set{tnadir,-100}

Set{vcross,250}
Set{vzenith,400}
Set{vnadir,-100}


add column average volume(90)
ADD COLUMN TREND
add column TRENDV
add column TRENDE
add column dvpct
add column valchg

/* enter your Upper Limit criteria */
set{UpperLim, High 13 week High}

/* enter your Lower Limit criteria */
set{LowerLim, Low 13 week Low}

set{LimDiff, UpperLim minus LowerLim}
set{PPDiff, CLOSE minus LowerLim}
set{PPDiv, PPDiff / LimDiff}
set{BallOn, PPDiv * 100}

set{PPDiffH, UpperLim - Close}
set{PPDivH, PPDiffH / Close}
set{BallOnH, PPDivH * 100}

set{PCT, LimDiff / LowerLim}

set{HiOp,high - open}
set{OpLo, open - low}

set{CCb,days(close is above close 1 day ago,100)}
set{CCa,days(close is below close 1 day ago,100)}
set{ClxCl, CCa - CCb}

set{HHb,days(High is above High 1 day ago,100)}
set{HHa,days(High is below High 1 day ago,100)}
set{HixHi, HHa - HHb}

set{LLb,days(Low is above Low 1 day ago,100)}
set{LLa,days(Low is below Low 1 day ago,100)}
set{LoxLo, LLa - LLb}

set{VolUp, days(volume is below volume 1 day ago,100)}
set{VolDn, days(volume is above volume 1 day ago,100)}
set{VlXvl, VolUp - VolDn}

set{vck1, volume 1 day ago }
set{vck, volume / vck1 }
set{vdbl, days(vck < 2, 100)}

Set{Bullpower, high minus ema(13)}
Set{Bearpower, low minus ema(13)}

set{BLb,days(BullPower is above BullPower 1 day ago,100)}
set{BLa,days(BullPower is below BullPower 1 day ago,100)}
set{BLxBL, BLa - BLb}

set{BRb,days(BearPower is above BearPower 1 day ago,100)}
set{BRa,days(BearPower is below BearPower 1 day ago,100)}
set{BRxBR, BRa - BRb}

set{RChg, count( UpperLim equal UpperLim 1 day ago, 1 ) }
set{SChg, count( LowerLim equal LowerLim 1 day ago, 1 ) }

/* Volatility Direction Filter Display */

set{BBDiff, Upper Bollinger Band(20) - Lower Bollinger Band(20) }

set{BBDb,days(BBDiff is above BBDiff 1 day ago,100)}
set{BBDa,days(BBDiff is below BBDiff 1 day ago,100)}
set{BBTrend, BBDa - BBDb}

set{ATRb,days(ATR(14) is above ATR(14) 1 day ago,100)}
set{ATRa,days(ATR(14) is below ATR(14) 1 day ago,100)}
set{ATRTrend, ATRa - ATRb}

/* profit had you bought the open 5 days ago and sold at the high */

set{High5, High 5 day High}
set{Profit, High5 - open 5 days ago}

/* Narrow Channel Breakout Display */

set{ High20, high 20 day high}
set{ Low20, low 20 day low}

set{ New20High, count( high above High20 1 day ago , 1 ) }
set{ New20Low, count( low below Low20 1 day ago , 1 ) }

/* column display */

add column HiOp
add column OpLo
add column Profit

add column BallOn
add column BallOnH
add column UpperLim {Resist}
add column LowerLim {Support}

add column RChg
add column SChg

add column New20High
add column New20Low

AND ADD COLUMN BBTrend
AND ADD COLUMN ATRTrend

/* PLOTS */

and draw UpperLim on plot price
and draw LowerLim on plot price

and draw t123
and draw tcross on plot t123
and draw tzenith on plot t123
and draw tnadir on plot t123

and draw v123
and draw vcross on plot v123
and draw vzenith on plot v123
and draw vnadir on plot v123

/* NORMALIZE accumulation distribution */

set{adval, INDPOSITION(accumulation distribution, 60) * 100 }

/* NORMALIZE momentum(12) */

set{moval, INDPOSITION(momentum(12), 60) * 100}

/* NORMALIZE rsi(2) */

set{rsval, RSI(2) }

/* NORMALIZE williams %r(10) */

set{wrval, INDPOSITION(williams %r(10), 60) * 100 }

/* DRAW THE MP RSIWLR CHART */

and draw wrval
and draw adval on plot wrval
and draw moval on plot wrval
and draw rsval on plot wrval

and ADD COLUMN T03a
and ADD COLUMN T05a
and ADD COLUMN T10a

and add column wrval
and add column adval
and add column rsval
and add column moval

and add column clxcl
and add column VlXvl
and add column Vdbl

and add column HixHi
and add column LoxLo

and add column Bullpower
and add column Bearpower
and add column BLxBL
and add column BRxBR

/* Selection Criteria */

and do not draw trend
and do not draw trendv

and market is not OTCBB

and wrval above 50
and adval above 50
and rsval above 50
and moval above 50

and close is between 5 and 10

and avg vol(5) above 500000
and avg vol(30) above 500000

add column industry

and Sort column 29 descending

and chart-length is 5 months

offset is 1 day]
leaddog
38 posts
msg #42900
- Ignore leaddog		 4/11/2006 11:15:36 PM

stocktrader

Thank you for taking the time to share your trading technique. If I understand, you place the stocks from the filter into a watch list monitor them after the open to find the ones which appear to be moving with the market and scale in if you are right. Is this correct?
stocktrader
294 posts
msg #42902
- Ignore stocktrader		 4/11/2006 11:36:10 PM

leaddog,

That's correct on the filter/watch list. I don't scale in/out all the time, but most. (it increases the broker fee...)

Human behavior is such that unless we have "real" money invested, our attention will be less. I typically go into a position with around $10k. If things look like they are going my way, I'll double the position. If things start looking like they are going against me, I'll cut the position in half. Sometimes this will be a knee-jerk reaction, if a stock makes a quick move. It can recover quickly though....the bigdogs jerk us small traders around pretty well sometimes :)
StockFetcher Forums · Filter Exchange · Who really wants to find the next NTRI?<< 1 ... 17 18 19 20 21 ... 31 >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.