StockFetcher Forums · Filter Exchange · Weekly Reversal Strategy<< 1 2 3 >>Post Follow-up
graftonian
1,089 posts
msg #154314
- Ignore graftonian		 10/14/2020 12:40:54 AM

@davesaint86
Thanks for bringing the strategy to our attention
graf
davesaint86
725 posts
msg #154319
- Ignore davesaint86		 10/14/2020 11:11:29 AM

If you enter offset the filter 12 days you will see the that out of 93 stocks return, most have had a positive gain since then. I think the goal of the strategy is to buy the reversal based off the bigger moves down, where the down turn last many weeks. Most stocks will move with the broad market going back up. I think that is the key.
Cheese
1,374 posts
msg #154321
- Ignore Cheese		 10/14/2020 11:48:31 AM

Thank you for your additional insights.
graftonian
1,089 posts
msg #154323
- Ignore graftonian
modified		 10/14/2020 12:46:42 PM

I am always confused when working with weekly charts. To assess my understanding, a question.
Was ACB a candidate on Monday morning?
Thankx, Graf
-----------------------------------
On further reading I see that ACB was not above average vol(50). I was using av30
graftonian
1,089 posts
msg #154324
- Ignore graftonian		 10/14/2020 2:22:54 PM

my feeble attempt to code for Weekly Reversal Candidates. No sorting yet, however will try to add my recent "Momentum Angle BS"

Fetcher[
/**********WEEKLY REVERSAL*************/
market is not OTCBB
chart-display is weekly
draw weekly average volume(50)
weekly volume 1 week ago > weekly average volume(50) /*rule 3*/
weekly close 1 week ago > weekly close 2 weeks ago /*RULE 2*/
Low 1 week ago < weekly low 2 weeks ago /*rule 1*/
low 1 week ago < weekly low 3 weeks ago
low 1 week ago < weekly low 4 weeks ago
/*********************B&W************************/
draw WMA(10) and draw WMA(50)

]
xarlor
581 posts
msg #154325
- Ignore xarlor
modified		 10/14/2020 2:49:02 PM

I banged out two filters for this strategy. One was using Steven Cawiezell's rules to the letter[1]. This should be run after the close on Fridays only and is part of the author's core reasoning why it works.

The second is adapting it to a daily swing trading strategy[2]. One entry rule I added is the ticker must be trending up. I also modified the exit rule to: close crosses above Upper BB for profit, or below Lower BB as a stop-loss.

[1] Note Steven Cawiezell uses the MA(50) of volume as his above-average volume indicator.
[2] Daily strategy may not be viable as the author states the weekly reversal works on two main principles. One, institutions shaking out weak (retail) hands and two, those same institutions building their positions over a course of the next several months.

Fetcher[
/* https://members.thetradersplan.com/income-video */
/* Weekly chart run only after close on Friday
Must have low < prior 3 low
Close > close 1 week ago
Above Average Volume
Enter at the open on Monday
Exit when close crosses below EMA(10)
*/

set{undercut1,count(low < low 1 week ago,1)}
set{undercut2,count(low < low 2 weeks ago,1)}
set{undercut3,count(low < low 3 weeks ago,1)}
set{green,count(close > close 1 week ago,1)}
set{volma,cma(volume,50)}
set{aav,count(volume > volma,1)}

set{long1,undercut1 * undercut2}
set{long2,long1 * undercut3}
set{long3,long2 * green}
set{long,long3 * aav}

long > 0
set{exit,count(close crossed below ema(10),1)}
exit > -1

add column undercut1
add column undercut2
add column undercut3
add column green
add column aav

chart-display weekly
chart-time 1 year
]



Fetcher[
/* https://members.thetradersplan.com/income-video */
/* Modified daily strategy by Xarlor
Must have low < prior 3 low
Close > close 1 week ago
Above Average Volume
Enter at the open next day
Exit when close crosses above Upper BB or below Lower BB
*/

optionable
close > wma(150) for last 100 days

set{undercut1,count(low < low 1 day ago,1)}
set{undercut2,count(low < low 2 days ago,1)}
set{undercut3,count(low < low 3 days ago,1)}
set{green,count(close > close 1 day ago,1)}
set{volma,cma(volume,50)}
set{aav,count(volume > volma,1)}

set{long1,undercut1 * undercut2}
set{long2,long1 * undercut3}
set{long3,long2 * green}
set{long,long3 * aav}

long > 0

set{exit1,count(close crossed above Upper Bollinger Band(20,2),1)}
set{exit2,count(close crossed below Lower Bollinger Band(20,2),1)}
set{exit,exit1 + exit2}
exit > -1
draw ema(10)

add column undercut1
add column undercut2
add column undercut3
add column green
add column aav
]
davesaint86
725 posts
msg #154326
- Ignore davesaint86		 10/14/2020 3:11:56 PM

Thanks Xarlor!


Cheese
1,374 posts
msg #154327
- Ignore Cheese		 10/14/2020 3:27:00 PM

Thank you, graftonian and xarlor !
graftonian
1,089 posts
msg #154328
- Ignore graftonian		 10/14/2020 3:44:41 PM

Last friday there were 47 hits, which would you have bought on Monday morning
Fetcher[
/**********WEEKLY REVERSAL*************/
market is not OTCBB
chart-display is weekly
draw weekly average volume(50)
weekly volume 1 week ago > weekly average volume(50) /*rule 3*/
weekly close 1 week ago > weekly close 2 weeks ago /*RULE 2*/
Low 1 week ago < weekly low 2 weeks ago /*rule 1*/
low 1 week ago < weekly low 3 weeks ago
low 1 week ago < weekly low 4 weeks ago
/*********************B&W************************/
/*momentum angle*/
/*Hull MA50*/
set{slow1, cwma(close, 25)}
set{slow2, 2 * slow1}
set{slow3, cwma(close, 50)}
set{valslow, slow2 - slow3}
set{H50, cwma(valslow, 7)}
/*Hull MA10*/
set{slow1A, cwma(close, 5)}
set{slow2A, 2 * slow1A}
set{slow3A, cwma(close, 10)}
set{valslowA, slow2A - slow3A}
set{H10, cwma(valslowA, 3)}
/*angle of MA slopes, or your choice of indicator 1 and 2*/
set{indicator1, H10} /********CHANGE INDICATOR1 HERE**************/
set{indicator2, H50} /********CHANGE INDICATOR2 HERE**************/
draw indicator1 on plot price draw indicator2 on plot price
set{slopeind1, 2 day slope of indicator1}
set{slopeind2, 2 day slope of indicator2}
set{radiansind1, slopeind1}
set{radiansind2, slopeind2}
set{atanind1, atan(radiansind1)}
set{atanind2, atan(radiansind2)}
set{hcircle, 180 / 3.14159}
set{angledegind1, atanind1 * hcircle}
set{angledegind2, atanind2 * hcircle}
set{CrossingAngle, angledegind1 - angledegind2}
/*sum the crossing angle and angledeg10ma*/
set{MomentumAngle, CrossingAngle + angledegind1}
add column MomentumAngle
sort on column 5 descending
add column separator
/*bells and whistles*/
draw momentumangle
draw momentumangle line at 0
/*determine Monday mornings purchase price(market order)*/
add column weekly open{mon morn market open}
/*and weekly howgozit*/
add column weekly close{latest price}
set{howgozit1, weekly close - weekly open}
set{howgozit2, howgozit1 / weekly open}
set{howgozit, howgozit2 * 100}
add column howgozit{howgozit%}
/********************DO NOT DRAW******************/
do not draw angleDegind2
]
graftonian
1,089 posts
msg #154330
- Ignore graftonian		 10/14/2020 4:13:41 PM

If anyone is interested in a list of last weeks candidates:
HRMY,API,NTES,NEOG,SGH,FUSN,IGLB,INBX,SPXB,LWAY,DMYT,MCV,VTC,USIG,TIP,SPLB,IMMR,HNGR,BWAY,LXU,WBND,ENX,UCL,AAU,GSK,PRT,SAFT,SPIP,GAU,TRVG,INZY,FCEL,LYFT,BMRG,RIBT,SMMU,AFIB,BORR,EYPT,AMCI,RISN,PVL,ANPC,PCG-D,NCNO,IMRA,


StockFetcher Forums · Filter Exchange · Weekly Reversal Strategy<< 1 2 3 >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.