StockFetcher Forums · Filter Exchange · Help Needed w/Filter - Three crossovers<< >>Post Follow-up
davesaint86
725 posts
msg #58479
- Ignore davesaint86		 12/24/2007 4:32:34 PM

Is there a way to build a filter basically where for example there is a slow sto crossover to the postives, a macd crossover and ther price passing up through the 10 SMA. When all through have crossed over the column Long will contain a 1 and the Short column will contain a 0 and do the opposite for the short filter? So all three would have to trigger before the Long or short signal triggers.

Thanks - Dave
TheRumpledOne
6,411 posts
msg #58480
- Ignore TheRumpledOne
modified		 12/24/2007 5:07:54 PM

Is there a way to build a filter basically where for example there is a slow sto crossover to the postives, a macd crossover and ther price passing up through the 10 SMA. When all through have crossed over the column Long will contain a 1 and the Short column will contain a 0 and do the opposite for the short filter? So all three would have to trigger before the Long or short signal triggers.

Fetcher[
set{test1, count(Slow Stochastic(10) Fast %K crossed above 0 , 1) }
set{test2, count(MACD Fast Line(12,26) crossed above the MACD Slow Line(12,26) , 1) }
set{test3, count(close crossed above ma(10) , 1) }

set{testa, test1 + test2}
set{LgTrigger, test3 + testa}

and add column LgTrigger
and add column test1
and add column test2
and add column test3

LgTrigger above 1

sort column 5 descending
]



A rare occurence for all 3 on the same day, don't you think?


davesaint86
725 posts
msg #58492
- Ignore davesaint86		 12/24/2007 10:36:28 PM

Thanks TRO. They all do not have to trigger the same day. Most likely I'm guessing the Slow Sto would trigger first "x" amount a days later than the MACD then 10 day SMA or vice-versa. It's fine if it takes a couple of weeks for all of them to trigger. Could you please explain the filter when you get a chance. I'm still trying to learn the syntax.

Davesaint
davesaint86
725 posts
msg #58493
- Ignore davesaint86
modified		 12/24/2007 10:49:17 PM

Fetcher[set{test1, count(Slow Stochastic(14,5) Fast %K crossed above 0 , 1) }
set{test2, count(MACD Fast Line(8,17) crossed above the MACD Slow Line(8,17) , 1) }
set{test3, count(close crossed above ma(10) , 1) }
and Average Volume is above 300000
and close is between 5 and 800

set{testa, test1 + test2}
set{LgTrigger, test3 + testa}

and add column LgTrigger
and add column test1
and add column test2
and add column test3
and draw CCI (20) line at 100.00 and draw CCI (20) line at -200.00
and draw Slow Stochastic(14,5) Fast %K line at 20.00 and draw Slow Stochastic(14,5) Fast %K line at 80.00
and draw Slow Stochastic(14,5) Fast %K line at 50.00
and draw MACD Fast Line(8,17) line at .15
and draw stochrsi (12) on plot stochrsi (25)
and draw StochRSI (12) line at .80 and draw StochRSI (25) line at .50
draw rsi(14) line at 75
draw rsi(14) line at 65
draw weekly rsi(5) on plot rsi(14)


LgTrigger above 1

sort column 5 descending


]



Look's good. Just your opinion for trend trading do you all think this a good filter. Get in long when all trigger, stay long for at least one of the three are positive. Get out or go short when all three cross below. I would like a few (5 or less stocks) to trade over and over. I'm tired of trading 10+ stocks. Please provide your opinions. Merry Christmas also.

Dave
TheRumpledOne
6,411 posts
msg #58503
- Ignore TheRumpledOne
modified		 12/25/2007 10:04:39 AM

Fetcher[set{test1, count(Slow Stochastic(14,5) Fast %K crossed above 0 , 30) }
set{test2, count(MACD Fast Line(8,17) crossed above the MACD Slow Line(8,17) , 30) }
set{test3, count(close crossed above ma(10) , 30) }
and Average Volume is above 300000
and close is between 5 and 800

set{testa, test1 + test2}
set{LgTrigger, test3 + testa}

and add column LgTrigger
and add column test1
and add column test2
and add column test3
and draw CCI (20) line at 100.00 and draw CCI (20) line at -200.00
and draw Slow Stochastic(14,5) Fast %K line at 20.00 and draw Slow Stochastic(14,5) Fast %K line at 80.00
and draw Slow Stochastic(14,5) Fast %K line at 50.00
and draw MACD Fast Line(8,17) line at .15
and draw stochrsi (12) on plot stochrsi (25)
and draw StochRSI (12) line at .80 and draw StochRSI (25) line at .50
draw rsi(14) line at 75
draw rsi(14) line at 65
draw weekly rsi(5) on plot rsi(14)


test1 above 0
test2 above 0
test3 above 0

sort column 5 descending
]




Now, all 3 have to have triggered in a 30 day period. Still no selections. I even tested at 100 days and no selections. Perhaps these 3 things don't happen at once. Not sure how to explain... it's your idea!!

But you said you wanted to trade the same 5 stocks over and over. May I suggest you use some of my TRO STAT SCAN filter displays to pick the stocks based on the statistics of their price movement rather than indicators.

Price is the input to indicators, not the other way around.



TheRumpledOne
6,411 posts
msg #58504
- Ignore TheRumpledOne
modified		 12/25/2007 10:12:15 AM

Fetcher[set{test1, count(Slow Stochastic(14,5) Fast %K crossed above 0 , 5) }
set{test2, count(MACD Fast Line(8,17) crossed above the MACD Slow Line(8,17) , 5) }
set{test3, count(close above ma(10) , 1) }
and Average Volume is above 300000
and close is between 5 and 800

set{testa, test1 + test2}
set{LgTrigger, test3 + testa}

and add column LgTrigger
and add column test1
and add column test2
and add column test3
and draw CCI (20) line at 100.00 and draw CCI (20) line at -200.00
and draw Slow Stochastic(14,5) Fast %K line at 20.00
and draw Slow Stochastic(14,5) Fast %K line at 80.00
and draw Slow Stochastic(14,5) Fast %K line at 50.00
and draw MACD Fast Line(8,17) line at .15
and draw stochrsi (12) on plot stochrsi (25)
and draw StochRSI (12) line at .80 and draw StochRSI (25) line at .50
draw rsi(14) line at 75
draw rsi(14) line at 65
draw weekly rsi(5) on plot rsi(14)

test1 above 0
test2 above 0
test3 above 0

sort column 5 descending
]



Changed the filter so the price has be to above the moving average rather than cross above it.


TheRumpledOne
6,411 posts
msg #58505
- Ignore TheRumpledOne		 12/25/2007 10:19:09 AM

Fetcher[
set{test1, count(Slow Stochastic(14,5) Fast %K crossed above 0 , 100) }
test1 above 0
]



This returns 0 stocks which means this condition hasn't happened in 5 months!!

I would say this SQUIGGLY needs to be replaced!!
TheRumpledOne
6,411 posts
msg #58506
- Ignore TheRumpledOne
modified		 12/25/2007 10:22:01 AM

Q) Just your opinion for trend trading do you all think this a good filter.

A) NO.

If you want trending stocks, give these a shot:

Fetcher[
/* Basic Filter for newbies and old pros */

set{E36b,days(ema(3) is above ema(6),100)}
set{E36a,days(ema(3) is below ema(6),100)}
set{E3xE6, E36a - E36b}

set{E50200b,days(ma(50) is above ma(200),100)}
set{E50200a,days(ma(50) is below ma(200),100)}
set{M50xM200, E50200a - E50200b}

set{E1326b,days(ema(13) is above ema(26),100)}
set{E1326a,days(ema(13) is below ema(26),100)}
set{E13xE26, E1326a - E1326b}

set{CCb,days(close is above close 1 day ago,100)}
set{CCa,days(close is below close 1 day ago,100)}
set{CxC, CCa - CCb}

set{E5b,days(close is above ema(5),100)}
set{E5a,days(close is below ema(5),100)}
set{CxE5, E5a - E5b}


set{E50b,days(close is above ma(50),100)}
set{E50a,days(close is below ma(50),100)}
set{CxM50, E50a - E50b}

set{E200b,days(close is above ma(200),100)}
set{E200a,days(close is below ma(200),100)}
set{CxM200, E200a - E200b}


set{T10, count(10 day slope of the close above 0,1)}
set{T60, count(60 day slope of the close above 0,1)}
set{T200, count(200 day slope of the close above 0,1)}

Set{a1, T200 * 1}
Set{a2, T60 * 10}
Set{a3, T10 * 100}

Set{aa, a1 + a2}
Set{TREND, aa + a3}

set{v, volume 1 day ago}
set{volinc, volume - v}
set{volpc, volinc / v}
set{volpct, volpc * 100}

set{VolZ, days(volume < 1,100)}
set{VolUp, days(volume is below volume 1 day ago,100)}
set{VolDn, days(volume is above volume 1 day ago,100)}
set{VolCnt, VolUp - VolDn}

set{vck1, volume 1 day ago }
set{vck, volume / vck1 }
set{vdbl, days(vck < 2, 100)}


and add column VolCnt
and add column Vdbl
and add column VolZ

and add column Trend

and add column CxC {CxC_}
and add column CxE5 {CxE5}

and add column E3xE6 {E3xE6}
and add column E13xE26 {E13xE26}


and add column CxM50
and add column CxM200
and add column M50xM200

add column rsi(2)
add column weekly rsi(2)

close above 1
volume above 1000000

TREND above 0

sort column 8 descending
]





Fetcher[
/* TREND CHANGE FILTER - WEEKLY TREND UP */

/* ENHANCED TREND DISPLAY - WEEKLY TREND UP */

set{T04 , count(04 week slope of the weekly close above 0,1)}
set{T13, count(13 week slope of the weekly close above 0,1)}
set{T26, count(26 week slope of the weekly close above 0,1)}
set{T52, count(52 week slope of the weekly close above 0,1)}
set{T104, count(104 week slope of the weekly close above 0,1)}

Set{a1, T104 * 1}
Set{a2, T52 * 10}
Set{a3, T26 * 100}
Set{a4, T13 * 1000}
Set{a5, T04 * 10000}

Set{aa, a1 + a2}
Set{ab, aa + a3}
Set{ac, ab + a4}
Set{TREND, ac + a5}

set{T04a,days(04 week slope of the weekly close below 0, 100)}
set{T13a,days(13 week slope of the weekly close below 0, 100)}
set{T26a,days(26 week slope of the weekly close below 0, 100)}
set{T52a,days(52 week slope of the weekly close below 0, 100)}
set{T104a,days(104 week slope of the weekly close below 0, 100)}

set{t1ago, trend 1 day ago}
set{t1diff, trend - t1ago}

ADD COLUMN TREND
ADD COLUMN t1ago

ADD COLUMN T04a
ADD COLUMN T13a
ADD COLUMN T26a
ADD COLUMN T52a
ADD COLUMN T104a

draw T04a
draw T13a on plot t04a
draw T26a on plot t04a
draw T52a on plot t04a
draw T104a on plot t04a

/* Selection Criteria */

t1diff above 0

close ABOVE .01

avg vol(5) above 500000
avg vol(30) above 500000

add column industry

Sort column 5 descending

chart-display is weekly
]



The TREND column shows if the trend is up(1) or down(0).

Search the forum for explanations of all the columns.



davesaint86
725 posts
msg #58512
- Ignore davesaint86		 12/25/2007 1:13:50 PM

Thank you sir. Sounds like a good idea you your TRO scan to select candindates that move alot Thank you for all your work.

Dave
StockFetcher Forums · Filter Exchange · Help Needed w/Filter - Three crossovers<< >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.